平均滤波器是线性类的窗口滤波器，用于平滑信号（图像）。 该滤波器作为低通滤波器工作。 滤波器背后的基本思想是信号（图像）的任何元素在其邻域取平均值。

---

如果我们有一个mxn矩阵，并且我们想在其上应用大小为k平均滤波器，那么对于矩阵p:(i,j)的每个点，该点的值将是平方中所有点的平均值

这个数字是用于大小为2的滤波的方形核，黄色方框是要平均的像素，并且所有网格是相邻像素的平方，该像素的新值将是它们的平均值。

问题是这个算法非常慢，特别是在大图像上，所以我想过使用GPGPU 。

现在的问题是 ，如果有可能，如何在cuda中实现这个功能？

---

这是一个尴尬的并行图像处理问题的经典案例，可以很容易地映射到CUDA框架。 平均滤波器在图像处理领域中被称为Box Filter。

最简单的方法是使用CUDA纹理进行过滤处理，因为边界条件可以很容易地通过纹理处理。

假设您在主机上分配了源和目标指针。 程序会是这样的。

分配足够大的内存以保存设备上的源图像和目标图像。

将源图像从主机复制到设备。

将源图像设备指针绑定到纹理。

指定适当的块大小和足够大的网格以覆盖图像的每个像素。

使用指定的网格和块大小启动过滤内核。

将结果复制回主机。

解开纹理

免费的设备指针。

盒式过滤器的样例实现

核心

texture<unsigned char, cudaTextureType2D> tex8u;

//Box Filter Kernel For Gray scale image with 8bit depth
__global__ void box_filter_kernel_8u_c1(unsigned char* output,const int width, const int height, const size_t pitch, const int fWidth, const int fHeight)
{
    int xIndex = blockIdx.x * blockDim.x + threadIdx.x;
    int yIndex = blockIdx.y * blockDim.y + threadIdx.y;

    const int filter_offset_x = fWidth/2;
    const int filter_offset_y = fHeight/2;

    float output_value = 0.0f;

    //Make sure the current thread is inside the image bounds
    if(xIndex<width && yIndex<height)
    {
        //Sum the window pixels
        for(int i= -filter_offset_x; i<=filter_offset_x; i++)
        {
            for(int j=-filter_offset_y; j<=filter_offset_y; j++)
            {
                //No need to worry about Out-Of-Range access. tex2D automatically handles it.
                output_value += tex2D(tex8u,xIndex + i,yIndex + j);
            }
        }

        //Average the output value
        output_value /= (fWidth * fHeight);

        //Write the averaged value to the output.
        //Transform 2D index to 1D index, because image is actually in linear memory
        int index = yIndex * pitch + xIndex;

        output[index] = static_cast<unsigned char>(output_value);
    }
}

包装功能：

void box_filter_8u_c1(unsigned char* CPUinput, unsigned char* CPUoutput, const int width, const int height, const int widthStep, const int filterWidth, const int filterHeight)
{

    /*
     * 2D memory is allocated as strided linear memory on GPU.
     * The terminologies "Pitch", "WidthStep", and "Stride" are exactly the same thing.
     * It is the size of a row in bytes.
     * It is not necessary that width = widthStep.
     * Total bytes occupied by the image = widthStep x height.
     */

    //Declare GPU pointer
    unsigned char *GPU_input, *GPU_output;

    //Allocate 2D memory on GPU. Also known as Pitch Linear Memory
    size_t gpu_image_pitch = 0;
    cudaMallocPitch<unsigned char>(&GPU_input,&gpu_image_pitch,width,height);
    cudaMallocPitch<unsigned char>(&GPU_output,&gpu_image_pitch,width,height);

    //Copy data from host to device.
    cudaMemcpy2D(GPU_input,gpu_image_pitch,CPUinput,widthStep,width,height,cudaMemcpyHostToDevice);

    //Bind the image to the texture. Now the kernel will read the input image through the texture cache.
    //Use tex2D function to read the image
    cudaBindTexture2D(NULL,tex8u,GPU_input,width,height,gpu_image_pitch);

    /*
     * Set the behavior of tex2D for out-of-range image reads.
     * cudaAddressModeBorder = Read Zero
     * cudaAddressModeClamp  = Read the nearest border pixel
     * We can skip this step. The default mode is Clamp.
     */
    tex8u.addressMode[0] = tex8u.addressMode[1] = cudaAddressModeBorder;

    /*
     * Specify a block size. 256 threads per block are sufficient.
     * It can be increased, but keep in mind the limitations of the GPU.
     * Older GPUs allow maximum 512 threads per block.
     * Current GPUs allow maximum 1024 threads per block
     */

    dim3 block_size(16,16);

    /*
     * Specify the grid size for the GPU.
     * Make it generalized, so that the size of grid changes according to the input image size
     */

    dim3 grid_size;
    grid_size.x = (width + block_size.x - 1)/block_size.x;  /*< Greater than or equal to image width */
    grid_size.y = (height + block_size.y - 1)/block_size.y; /*< Greater than or equal to image height */

    //Launch the kernel
    box_filter_kernel_8u_c1<<<grid_size,block_size>>>(GPU_output,width,height,gpu_image_pitch,filterWidth,filterHeight);

    //Copy the results back to CPU
    cudaMemcpy2D(CPUoutput,widthStep,GPU_output,gpu_image_pitch,width,height,cudaMemcpyDeviceToHost);

    //Release the texture
    cudaUnbindTexture(tex8u);

    //Free GPU memory
    cudaFree(GPU_input);
    cudaFree(GPU_output);
}

好消息是你不必自己实现过滤器。 CUDA Toolkit附带由NVIDIA制造的名为NVIDIA Performance Primitives aka NPP的免费信号和图像处理库。 NPP使用支持CUDA的GPU来加速处理。 平均过滤器已在NPP中实施。 当前版本的NPP（5.0）支持8位，1通道和4通道图像。 功能是：

nppiFilterBox_8u_C1R用于1通道图像。

nppiFilterBox_8u_C4R 4通道图像。

---

一些基本思想/步骤：

将图像数据从CPU复制到GPU

调用内核来构建每行（水平）的平均值并将其存储在共享内存中。

调用内核来构建每列（垂直）的平均值并将其存储在全局内存中。

将数据复制回CPU内存。

您应该可以通过2D内存和多维内核调用轻松地进行扩展。

---

如果过滤器的大小是正常的并且不是很大，那么平均过滤器对于使用CUDA来说是非常好的情况。 您可以使用方块设置它，并且块的每个线程都负责计算一个像素的值，方法是对其邻域进行求和和平均。

如果将图像存储在全局内存中，则可以轻松进行编程，但会产生很多银行冲突。 一种可能的优化是将图像的块加载到块的共享内存中。 使用幻像元素（以便在查找相邻像素时不会超出共享块的尺寸），可以计算块内像素的平均值。

唯一需要注意的是如何最终完成“拼接”，因为共享内存块将会重叠（由于额外的“填充”像素），并且您不想计算它们的值两次。

链接地址: http://www.djcxy.com/p/25393.html

上一篇: Cuda Image average filter

下一篇: Is cuda suitable for array filtering